66 lines
2.3 KiB
Nix
66 lines
2.3 KiB
Nix
{ self, lib, ... }:
|
|
|
|
let
|
|
inherit (builtins) attrValues readDir pathExists concatLists;
|
|
inherit (lib) id mapAttrsToList filterAttrs hasPrefix hasSuffix nameValuePair removeSuffix;
|
|
inherit (self.attrs) mapFilterAttrs;
|
|
in
|
|
rec {
|
|
# Returns an attribute set with the keys being the files in a directory
|
|
# and the values a function applied to their paths
|
|
# Only *.nix files and directories with a default.nix file are considered.
|
|
# The ".nix" suffix is removed from the keys of the attribute set.
|
|
mapModules = dir: fn:
|
|
mapFilterAttrs
|
|
(n: v:
|
|
v != null &&
|
|
!(hasPrefix "_" n))
|
|
(n: v:
|
|
let path = "${toString dir}/${n}"; in
|
|
if v == "directory" && pathExists "${path}/default.nix"
|
|
then nameValuePair n (fn path)
|
|
else if v == "regular" &&
|
|
n != "default.nix" &&
|
|
hasSuffix ".nix" n
|
|
then nameValuePair (removeSuffix ".nix" n) (fn path)
|
|
else nameValuePair "" null)
|
|
(readDir dir);
|
|
|
|
# Like mapModules above, but it just returns the values
|
|
# (map the function fn over the files in a directory)
|
|
mapModules' = dir: fn:
|
|
attrValues (mapModules dir fn);
|
|
|
|
# Like mapModules, but recursive. That is, if there is a directory, the
|
|
# value will be another attribute set with its contents as keys and the funcion
|
|
# applied to them as values.
|
|
mapModulesRec = dir: fn:
|
|
mapFilterAttrs
|
|
(n: v:
|
|
v != null &&
|
|
!(hasPrefix "_" n))
|
|
(n: v:
|
|
let path = "${toString dir}/${n}"; in
|
|
if v == "directory"
|
|
then nameValuePair n (mapModulesRec path fn)
|
|
else if v == "regular" && n != "default.nix" && hasSuffix ".nix" n
|
|
then nameValuePair (removeSuffix ".nix" n) (fn path)
|
|
else nameValuePair "" null)
|
|
(readDir dir);
|
|
|
|
# Like mapModulesRec but flattened and only the values. That is, it returns a list
|
|
# with fn applied to all *.nix files within the directory and subdirectories
|
|
# excluding default.nix files.
|
|
mapModulesRec' = dir: fn:
|
|
let
|
|
dirs =
|
|
mapAttrsToList
|
|
(k: _: "${dir}/${k}")
|
|
(filterAttrs
|
|
(n: v: v == "directory" && !(hasPrefix "_" n))
|
|
(readDir dir));
|
|
files = attrValues (mapModules dir id);
|
|
paths = files ++ concatLists (map (d: mapModulesRec' d id) dirs);
|
|
in map fn paths;
|
|
}
|